[TC] скрипты для мымоусе
Привет, всем!
Вот я регулирую произношение цифер такими скриптами:
Script NomeraPoOdnomu ()
SetJCFOption (OPT_NUMBERS, 1)
SayString("читать числа единично ")
EndScript
Script NomeraParami ()
SetJCFOption (OPT_NUMBERS, 2)
SayString("читать числа парами")
EndScript
Script NomeraPolno ()
SetJCFOption (OPT_NUMBERS, 3)
SayString("читать числа полностью")
EndScript
Они работают, но стоит перейти в другое приложение и вернуться обратно как
настройка меняется т. е. поставил читать парами,а возвращается как стоит в
настройках.
Как зделать, чтоб если переключил по скрипту то настройка запоминалась?
Спасибо.
здравствуйте алекс.
после моей подписи идут два скрипта.
первый для переключения произношения чисел единично, по парно и полно.
второй для переключения словаря.
оба скрипта вносят изменения, которые остаются даже после перезагрузки
джавс.
С уважением к вам Васильев Андрей.
Город Ухта.
;переключение произношения чисел
Script numbers ()
var
Int a,
int nOffSet,
int Level,
String DefaultJCF
let DefaultJCF = GetJAWSSettingsDirectory () + "\\Default.JCF"
let nOffSet = 1
let Level = GetJCFOption (OPT_NUMBERS)
If (Level == 3) then
SetJCFOption (OPT_NUMBERS, 1)
Else
SetJCFOption (OPT_NUMBERS, Level + nOffSet)
endIf
If (Level == 1) then
SayString ("читать парами")
IniWriteInteger ("options", "numbers", 2, DefaultJCF)
ElIf (Level == 2) then
SayString ("читать полно")
IniWriteInteger ("options", "numbers", 3, DefaultJCF)
ElIf (Level == 3) then
SayString ("читать единично")
IniWriteInteger ("options", "numbers", 1, DefaultJCF)
endIf
EndScript
;словарь
Script DictionaryOnOff ()
var
Int a,
String DefaultJCF
let DefaultJCF = GetJAWSSettingsDirectory () + "\\Default.JCF"
if GetJCFOption (OPT_DICTIONARY) then
SayString ("Словарь выключен")
SetJCFOption (OPT_DICTIONARY, 0)
IniWriteInteger ("options", "Dictionary", 0, DefaultJCF)
else
SetJCFOption (OPT_DICTIONARY, 1)
SayString("Словарь включон")
IniWriteInteger ("options", "Dictionary", 1, DefaultJCF)
EndIf
EndScript